Initial put

quickstart/101-batch-pools-with-job/README.md

@@ -0,0 +1,21 @@
+# Azure Batch
+
+Deploy an Azure Batch account and two batch pools.
+
+## Terraform resource types
+
+- [random_pet](https://registry.terraform.io/providers/hashicorp/random/latest/docs/resources/pet)
+- [azurerm_resource_group](https://registry.terraform.io/providers/hashicorp/azurerm/latest/docs/resources/resource_group)
+- [random_string](https://registry.terraform.io/providers/hashicorp/random/latest/docs/resources/string)
+- [azurerm_storage_account](https://registry.terraform.io/providers/hashicorp/azurerm/latest/docs/resources/storage_account)
+- [azurerm_batch_account](https://registry.terraform.io/providers/hashicorp/azurerm/latest/docs/resources/batch_account)
+- [azurerm_batch_pool](https://registry.terraform.io/providers/hashicorp/azurerm/latest/docs/resources/batch_pool)
+
+## Variables
+
+| Name | Description | Default |
+|-|-|-|
+| `resource_group_name_prefix` | Prefix of the resource group name that's combined with a random ID so name is unique in your Azure subscription. | rg |
+| `resource_group_location` | Location of the resource group. | eastus |
+
+## Example

quickstart/101-batch-pools-with-job/main.tf

@@ -0,0 +1,114 @@
+resource "random_pet" "rg_name" {
+  prefix = var.resource_group_name_prefix
+}
+
+resource "azurerm_resource_group" "rg" {
+  location = var.resource_group_location
+  name     = random_pet.rg_name.id
+}
+
+resource "random_string" "storage_account_name" {
+  length  = 8
+  lower   = true
+  numeric = false
+  special = false
+  upper   = false
+}
+
+resource "azurerm_storage_account" "example" {
+  name                     = random_string.storage_account_name.result
+  resource_group_name      = azurerm_resource_group.rg.name
+  location                 = azurerm_resource_group.rg.location
+  account_tier             = "Standard"
+  account_replication_type = "LRS"
+}
+
+resource "random_string" "batch_account_name" {
+  length  = 8
+  lower   = true
+  numeric = false
+  special = false
+  upper   = false
+}
+
+resource "azurerm_batch_account" "example" {
+  name                                = random_string.batch_account_name.result
+  resource_group_name                 = azurerm_resource_group.rg.name
+  location                            = azurerm_resource_group.rg.location
+  storage_account_id                  = azurerm_storage_account.example.id
+  storage_account_authentication_mode = "StorageKeys"
+}
+
+resource "random_pet" "azurerm_batch_pool_name" {
+  prefix = "pool"
+}
+
+resource "azurerm_batch_pool" "fixed" {
+  name                = "${random_pet.azurerm_batch_pool_name.id}-fixed-pool"
+  resource_group_name = azurerm_resource_group.rg.name
+  account_name        = azurerm_batch_account.example.name
+  display_name        = "Fixed Scale Pool"
+  vm_size             = "Standard_A1"
+  node_agent_sku_id   = "batch.node.ubuntu 22.04"
+
+  fixed_scale {
+    target_dedicated_nodes = 2
+    resize_timeout         = "PT15M"
+  }
+
+  storage_image_reference {
+    publisher = "Canonical"
+    offer     = "0001-com-ubuntu-server-jammy"
+    sku       = "22_04-lts"
+    version   = "latest"
+  }
+
+  start_task {
+    command_line       = "echo 'Hello World from $env'"
+    task_retry_maximum = 1
+    wait_for_success   = true
+
+    common_environment_properties = {
+      env = "TEST"
+    }
+
+    user_identity {
+      auto_user {
+        elevation_level = "NonAdmin"
+        scope           = "Task"
+      }
+    }
+  }
+
+  metadata = {
+    "tagName" = "Example tag"
+  }
+}
+
+resource "azurerm_batch_pool" "autopool" {
+  name                = "${random_pet.azurerm_batch_pool_name.id}-autoscale-pool"
+  resource_group_name = azurerm_resource_group.rg.name
+  account_name        = azurerm_batch_account.example.name
+  display_name        = "Auto Scale Pool"
+  vm_size             = "Standard_A1"
+  node_agent_sku_id   = "batch.node.ubuntu 22.04"
+
+  auto_scale {
+    evaluation_interval = "PT15M"
+
+    formula = <<EOF
+      startingNumberOfVMs = 1;
+      maxNumberofVMs = 25;
+      pendingTaskSamplePercent = $PendingTasks.GetSamplePercent(180 * TimeInterval_Second);
+      pendingTaskSamples = pendingTaskSamplePercent < 70 ? startingNumberOfVMs : avg($PendingTasks.GetSample(180 * TimeInterval_Second));
+      $TargetDedicatedNodes=min(maxNumberofVMs, pendingTaskSamples);
+EOF
+  }
+
+  storage_image_reference {
+    publisher = "Canonical"
+    offer     = "0001-com-ubuntu-server-jammy"
+    sku       = "22_04-lts"
+    version   = "latest"
+  }
+}

quickstart/101-batch-pools-with-job/outputs.tf

@@ -0,0 +1,19 @@
+output "resource_group_name" {
+  value = azurerm_resource_group.rg.name
+}
+
+output "storage_account_name" {
+  value = azurerm_storage_account.example.name
+}
+
+output "batch_account_name" {
+  value = azurerm_batch_account.example.name
+}
+
+output "batch_pool_fixed_name" {
+  value = azurerm_batch_pool.fixed.name
+}
+
+output "batch_pool_autopool_name" {
+  value = azurerm_batch_pool.autopool.name
+}

quickstart/101-batch-pools-with-job/providers.tf

@@ -0,0 +1,18 @@
+terraform {
+  required_version = ">=1.0"
+
+  required_providers {
+    azurerm = {
+      source  = "hashicorp/azurerm"
+      version = "~>3.0"
+    }
+    random = {
+      source  = "hashicorp/random"
+      version = "~>3.0"
+    }
+  }
+}
+
+provider "azurerm" {
+  features {}
+}

quickstart/101-batch-pools-with-job/variables.tf

@@ -0,0 +1,11 @@
+variable "resource_group_location" {
+  type        = string
+  default     = "eastus"
+  description = "Location of the resource group."
+}
+
+variable "resource_group_name_prefix" {
+  type        = string
+  default     = "rg"
+  description = "Prefix of the resource group name that's combined with a random ID so name is unique in your Azure subscription."
+}