137 строки
3.7 KiB
Plaintext
137 строки
3.7 KiB
Plaintext
/*
|
|
* Copyright (c) Facebook, Inc. and its affiliates.
|
|
*
|
|
* This source code is licensed under the MIT license found in the
|
|
* LICENSE file in the root directory of this source tree.
|
|
*/
|
|
|
|
#import "RCTAppearance.h"
|
|
|
|
#import <FBReactNativeSpec/FBReactNativeSpec.h>
|
|
#import <React/RCTConstants.h>
|
|
#import <React/RCTEventEmitter.h>
|
|
|
|
#import "CoreModulesPlugins.h"
|
|
|
|
using namespace facebook::react;
|
|
|
|
NSString *const RCTAppearanceColorSchemeLight = @"light";
|
|
NSString *const RCTAppearanceColorSchemeDark = @"dark";
|
|
|
|
static BOOL sAppearancePreferenceEnabled = YES;
|
|
void RCTEnableAppearancePreference(BOOL enabled) {
|
|
sAppearancePreferenceEnabled = enabled;
|
|
}
|
|
|
|
static NSString *sColorSchemeOverride = nil;
|
|
void RCTOverrideAppearancePreference(NSString *const colorSchemeOverride) {
|
|
sColorSchemeOverride = colorSchemeOverride;
|
|
}
|
|
|
|
static NSString *RCTColorSchemePreference(UITraitCollection *traitCollection)
|
|
{
|
|
#if defined(__IPHONE_OS_VERSION_MAX_ALLOWED) && defined(__IPHONE_13_0) && __IPHONE_OS_VERSION_MAX_ALLOWED >= __IPHONE_13_0
|
|
if (@available(iOS 13.0, *)) {
|
|
static NSDictionary *appearances;
|
|
static dispatch_once_t onceToken;
|
|
|
|
if (sColorSchemeOverride) {
|
|
return sColorSchemeOverride;
|
|
}
|
|
|
|
dispatch_once(&onceToken, ^{
|
|
appearances = @{
|
|
@(UIUserInterfaceStyleLight): RCTAppearanceColorSchemeLight,
|
|
@(UIUserInterfaceStyleDark): RCTAppearanceColorSchemeDark
|
|
};
|
|
});
|
|
|
|
if (!sAppearancePreferenceEnabled) {
|
|
// Return the default if the app doesn't allow different color schemes.
|
|
return RCTAppearanceColorSchemeLight;
|
|
}
|
|
|
|
traitCollection = traitCollection ?: [UITraitCollection currentTraitCollection];
|
|
return appearances[@(traitCollection.userInterfaceStyle)] ?: RCTAppearanceColorSchemeLight;
|
|
}
|
|
#endif
|
|
|
|
// Default to light on older OS version - same behavior as Android.
|
|
return RCTAppearanceColorSchemeLight;
|
|
}
|
|
|
|
@interface RCTAppearance () <NativeAppearanceSpec>
|
|
@end
|
|
|
|
@implementation RCTAppearance
|
|
{
|
|
NSString *_currentColorScheme;
|
|
}
|
|
|
|
RCT_EXPORT_MODULE(Appearance)
|
|
|
|
+ (BOOL)requiresMainQueueSetup
|
|
{
|
|
return YES;
|
|
}
|
|
|
|
- (dispatch_queue_t)methodQueue
|
|
{
|
|
return dispatch_get_main_queue();
|
|
}
|
|
|
|
- (std::shared_ptr<TurboModule>)getTurboModuleWithJsInvoker:(std::shared_ptr<CallInvoker>)jsInvoker
|
|
{
|
|
return std::make_shared<NativeAppearanceSpecJSI>(self, jsInvoker);
|
|
}
|
|
|
|
RCT_EXPORT_SYNCHRONOUS_TYPED_METHOD(NSString *, getColorScheme)
|
|
{
|
|
_currentColorScheme = RCTColorSchemePreference(nil);
|
|
return _currentColorScheme;
|
|
}
|
|
|
|
- (void)appearanceChanged:(NSNotification *)notification
|
|
{
|
|
NSDictionary *userInfo = [notification userInfo];
|
|
UITraitCollection *traitCollection = nil;
|
|
if (userInfo) {
|
|
traitCollection = userInfo[RCTUserInterfaceStyleDidChangeNotificationTraitCollectionKey];
|
|
}
|
|
NSString *newColorScheme = RCTColorSchemePreference(traitCollection);
|
|
if (![_currentColorScheme isEqualToString:newColorScheme]) {
|
|
_currentColorScheme = newColorScheme;
|
|
[self sendEventWithName:@"appearanceChanged" body:@{@"colorScheme": newColorScheme}];
|
|
}
|
|
}
|
|
|
|
#pragma mark - RCTEventEmitter
|
|
|
|
- (NSArray<NSString *> *)supportedEvents
|
|
{
|
|
return @[@"appearanceChanged"];
|
|
}
|
|
|
|
- (void)startObserving
|
|
{
|
|
if (@available(iOS 13.0, *)) {
|
|
[[NSNotificationCenter defaultCenter] addObserver:self
|
|
selector:@selector(appearanceChanged:)
|
|
name:RCTUserInterfaceStyleDidChangeNotification
|
|
object:nil];
|
|
}
|
|
}
|
|
|
|
- (void)stopObserving
|
|
{
|
|
if (@available(iOS 13.0, *)) {
|
|
[[NSNotificationCenter defaultCenter] removeObserver:self];
|
|
}
|
|
}
|
|
|
|
@end
|
|
|
|
Class RCTAppearanceCls(void) {
|
|
return RCTAppearance.class;
|
|
}
|