501 строка
16 KiB
Plaintext
501 строка
16 KiB
Plaintext
# Copyright (c) 2013 The Chromium Authors. All rights reserved.
|
|
# Use of this source code is governed by a BSD-style license that can be
|
|
# found in the LICENSE file.
|
|
|
|
import("//build/config/allocator.gni")
|
|
import("//build/config/chrome_build.gni")
|
|
import("//build/config/chromecast_build.gni")
|
|
import("//build/config/crypto.gni")
|
|
import("//build/config/dcheck_always_on.gni")
|
|
import("//build/config/features.gni")
|
|
import("//build/config/sanitizers/sanitizers.gni")
|
|
import("//build/config/ui.gni")
|
|
import("//build/toolchain/goma.gni")
|
|
|
|
# One common error that happens is that GYP-generated headers within gen/ get
|
|
# included rather than the GN-generated ones within gen/ subdirectories.
|
|
# TODO(GYP_GONE): Remove once GYP is gone (as well as exec_script exception).
|
|
assert(
|
|
exec_script("//build/dir_exists.py", [ "obj.host" ], "string") == "False",
|
|
"GYP artifacts detected in $root_build_dir.$0x0A" +
|
|
"You must wipe this directory before building with GN.")
|
|
|
|
declare_args() {
|
|
# When set (the default) enables C++ iterator debugging in debug builds.
|
|
# Iterator debugging is always off in release builds (technically, this flag
|
|
# affects the "debug" config, which is always available but applied by
|
|
# default only in debug builds).
|
|
#
|
|
# Iterator debugging is generally useful for catching bugs. But it can
|
|
# introduce extra locking to check the state of an iterator against the state
|
|
# of the current object. For iterator- and thread-heavy code, this can
|
|
# significantly slow execution.
|
|
enable_iterator_debugging = true
|
|
|
|
# Normally we try to decide whether to use precompiled headers or
|
|
# not based on the other build arguments, but in some cases it is
|
|
# easiest to force them off explicitly.
|
|
disable_precompiled_headers = false
|
|
}
|
|
|
|
# ==============================================
|
|
# PLEASE DO NOT ADD MORE THINGS TO THIS LIST
|
|
# ==============================================
|
|
#
|
|
# Legacy feature defines applied to all targets.
|
|
#
|
|
# These are applied to every single compile in the build and most of them are
|
|
# only relevant to a few files. This bloats command lines and causes
|
|
# unnecessary recompiles when flags are flipped.
|
|
#
|
|
# To pass defines to source code from the build, use the buildflag system which
|
|
# will write headers containing the defines you need. This isolates the define
|
|
# and means its definition can participate in the build graph, only recompiling
|
|
# things when it actually changes.
|
|
#
|
|
# See //build/buildflag_header.gni for inntructions on generating headers.
|
|
#
|
|
# This will also allow you to scope your build flag to a BUILD.gn file (or a
|
|
# .gni file if you need it from more than one place) rather than making global
|
|
# flags. See //build/config/BUILDCONFIG.gn for advice on where to define
|
|
# build flags.
|
|
config("feature_flags") {
|
|
# Don't use deprecated V8 APIs anywhere.
|
|
defines = [ "V8_DEPRECATION_WARNINGS" ]
|
|
if (enable_mdns) {
|
|
defines += [ "ENABLE_MDNS=1" ]
|
|
}
|
|
if (enable_notifications) {
|
|
defines += [ "ENABLE_NOTIFICATIONS" ]
|
|
}
|
|
if (enable_pepper_cdms) {
|
|
# TODO(brettw) should probably be "=1"
|
|
defines += [ "ENABLE_PEPPER_CDMS" ]
|
|
}
|
|
if (enable_browser_cdms) {
|
|
# TODO(brettw) should probably be "=1"
|
|
defines += [ "ENABLE_BROWSER_CDMS" ]
|
|
}
|
|
if (enable_plugins) {
|
|
defines += [ "ENABLE_PLUGINS=1" ]
|
|
}
|
|
if (enable_pdf) {
|
|
defines += [ "ENABLE_PDF=1" ]
|
|
}
|
|
if (enable_basic_printing || enable_print_preview) {
|
|
# Convenience define for ENABLE_BASIC_PRINTING || ENABLE_PRINT_PREVIEW.
|
|
defines += [ "ENABLE_PRINTING=1" ]
|
|
if (enable_basic_printing) {
|
|
# Enable basic printing support and UI.
|
|
defines += [ "ENABLE_BASIC_PRINTING=1" ]
|
|
}
|
|
if (enable_print_preview) {
|
|
# Enable printing with print preview.
|
|
# Can be defined without ENABLE_BASIC_PRINTING.
|
|
defines += [ "ENABLE_PRINT_PREVIEW=1" ]
|
|
}
|
|
if ((enable_basic_printing && is_win) || enable_print_preview) {
|
|
# Windows basic printing or print preview requires pdf enabled.
|
|
assert(enable_pdf,
|
|
"Windows basic printing or print preview needs pdf: " +
|
|
"set enable_pdf=true.")
|
|
}
|
|
}
|
|
if (enable_spellcheck) {
|
|
defines += [ "ENABLE_SPELLCHECK=1" ]
|
|
}
|
|
if (use_browser_spellchecker) {
|
|
defines += [ "USE_BROWSER_SPELLCHECKER=1" ]
|
|
}
|
|
if (dcheck_always_on) {
|
|
defines += [ "DCHECK_ALWAYS_ON=1" ]
|
|
}
|
|
if (use_udev) {
|
|
# TODO(brettw) should probably be "=1".
|
|
defines += [ "USE_UDEV" ]
|
|
}
|
|
if (ui_compositor_image_transport) {
|
|
# TODO(brettw) should probably be "=1".
|
|
defines += [ "UI_COMPOSITOR_IMAGE_TRANSPORT" ]
|
|
}
|
|
if (use_ash) {
|
|
defines += [ "USE_ASH=1" ]
|
|
}
|
|
if (use_aura) {
|
|
defines += [ "USE_AURA=1" ]
|
|
}
|
|
if (use_pango) {
|
|
defines += [ "USE_PANGO=1" ]
|
|
}
|
|
if (use_cairo) {
|
|
defines += [ "USE_CAIRO=1" ]
|
|
}
|
|
if (use_clipboard_aurax11) {
|
|
defines += [ "USE_CLIPBOARD_AURAX11=1" ]
|
|
}
|
|
if (use_default_render_theme) {
|
|
defines += [ "USE_DEFAULT_RENDER_THEME=1" ]
|
|
}
|
|
if (use_glib) {
|
|
defines += [ "USE_GLIB=1" ]
|
|
}
|
|
if (use_openssl_certs) {
|
|
defines += [ "USE_OPENSSL_CERTS=1" ]
|
|
}
|
|
if (use_nss_certs) {
|
|
defines += [ "USE_NSS_CERTS=1" ]
|
|
}
|
|
if (use_ozone) {
|
|
defines += [ "USE_OZONE=1" ]
|
|
}
|
|
if (use_x11) {
|
|
defines += [ "USE_X11=1" ]
|
|
}
|
|
if (use_allocator != "tcmalloc") {
|
|
defines += [ "NO_TCMALLOC" ]
|
|
}
|
|
if (is_asan || is_lsan || is_tsan || is_msan) {
|
|
defines += [
|
|
"MEMORY_TOOL_REPLACES_ALLOCATOR",
|
|
"MEMORY_SANITIZER_INITIAL_SIZE",
|
|
]
|
|
}
|
|
if (is_asan) {
|
|
defines += [ "ADDRESS_SANITIZER" ]
|
|
}
|
|
if (is_lsan) {
|
|
defines += [
|
|
"LEAK_SANITIZER",
|
|
"WTF_USE_LEAK_SANITIZER=1",
|
|
]
|
|
}
|
|
if (is_tsan) {
|
|
defines += [
|
|
"THREAD_SANITIZER",
|
|
"DYNAMIC_ANNOTATIONS_EXTERNAL_IMPL=1",
|
|
"WTF_USE_DYNAMIC_ANNOTATIONS_NOIMPL=1",
|
|
]
|
|
}
|
|
if (is_msan) {
|
|
defines += [ "MEMORY_SANITIZER" ]
|
|
}
|
|
if (is_ubsan || is_ubsan_null || is_ubsan_vptr || is_ubsan_security) {
|
|
defines += [ "UNDEFINED_SANITIZER" ]
|
|
}
|
|
if (use_external_popup_menu) {
|
|
defines += [ "USE_EXTERNAL_POPUP_MENU=1" ]
|
|
}
|
|
if (enable_webrtc) {
|
|
defines += [ "ENABLE_WEBRTC=1" ]
|
|
}
|
|
if (!enable_nacl) {
|
|
defines += [ "DISABLE_NACL" ]
|
|
}
|
|
if (enable_extensions) {
|
|
defines += [ "ENABLE_EXTENSIONS=1" ]
|
|
}
|
|
if (enable_task_manager) {
|
|
defines += [ "ENABLE_TASK_MANAGER=1" ]
|
|
}
|
|
if (enable_themes) {
|
|
defines += [ "ENABLE_THEMES=1" ]
|
|
}
|
|
if (enable_captive_portal_detection) {
|
|
defines += [ "ENABLE_CAPTIVE_PORTAL_DETECTION=1" ]
|
|
}
|
|
if (enable_session_service) {
|
|
defines += [ "ENABLE_SESSION_SERVICE=1" ]
|
|
}
|
|
if (enable_rlz) {
|
|
defines += [ "ENABLE_RLZ" ]
|
|
}
|
|
if (enable_plugin_installation) {
|
|
defines += [ "ENABLE_PLUGIN_INSTALLATION=1" ]
|
|
}
|
|
if (enable_app_list) {
|
|
defines += [ "ENABLE_APP_LIST=1" ]
|
|
}
|
|
if (enable_supervised_users) {
|
|
defines += [ "ENABLE_SUPERVISED_USERS=1" ]
|
|
}
|
|
if (enable_service_discovery) {
|
|
defines += [ "ENABLE_SERVICE_DISCOVERY=1" ]
|
|
}
|
|
if (enable_image_loader_extension) {
|
|
defines += [ "IMAGE_LOADER_EXTENSION=1" ]
|
|
}
|
|
if (enable_wayland_server) {
|
|
defines += [ "ENABLE_WAYLAND_SERVER=1" ]
|
|
}
|
|
if (enable_wifi_display) {
|
|
defines += [ "ENABLE_WIFI_DISPLAY=1" ]
|
|
}
|
|
if (proprietary_codecs) {
|
|
defines += [ "USE_PROPRIETARY_CODECS" ]
|
|
}
|
|
if (enable_hangout_services_extension) {
|
|
defines += [ "ENABLE_HANGOUT_SERVICES_EXTENSION=1" ]
|
|
}
|
|
if (enable_video_hole) {
|
|
defines += [ "VIDEO_HOLE=1" ]
|
|
}
|
|
if (safe_browsing_mode == 1) {
|
|
defines += [ "FULL_SAFE_BROWSING" ]
|
|
defines += [ "SAFE_BROWSING_CSD" ]
|
|
defines += [ "SAFE_BROWSING_DB_LOCAL" ]
|
|
} else if (safe_browsing_mode == 2) {
|
|
defines += [ "SAFE_BROWSING_DB_REMOTE" ]
|
|
}
|
|
if (is_official_build) {
|
|
defines += [ "OFFICIAL_BUILD" ]
|
|
}
|
|
if (is_chrome_branded) {
|
|
defines += [ "GOOGLE_CHROME_BUILD" ]
|
|
} else {
|
|
defines += [ "CHROMIUM_BUILD" ]
|
|
}
|
|
if (enable_media_router) {
|
|
defines += [ "ENABLE_MEDIA_ROUTER=1" ]
|
|
}
|
|
if (enable_webvr) {
|
|
defines += [ "ENABLE_WEBVR" ]
|
|
}
|
|
if (is_syzyasan) {
|
|
defines += [
|
|
"SYZYASAN",
|
|
"MEMORY_TOOL_REPLACES_ALLOCATOR",
|
|
"MEMORY_SANITIZER_INITIAL_SIZE",
|
|
]
|
|
}
|
|
if (!fieldtrial_testing_like_official_build && !is_chrome_branded) {
|
|
defines += [ "FIELDTRIAL_TESTING_ENABLED" ]
|
|
}
|
|
|
|
# ==============================================
|
|
# PLEASE DO NOT ADD MORE THINGS TO THIS LIST
|
|
# ==============================================
|
|
#
|
|
# See the comment at the top.
|
|
}
|
|
|
|
# Debug/release ----------------------------------------------------------------
|
|
|
|
config("debug") {
|
|
defines = [
|
|
"_DEBUG",
|
|
"DYNAMIC_ANNOTATIONS_ENABLED=1",
|
|
"WTF_USE_DYNAMIC_ANNOTATIONS=1",
|
|
]
|
|
|
|
if (is_nacl) {
|
|
defines += [ "DYNAMIC_ANNOTATIONS_PREFIX=NACL_" ]
|
|
}
|
|
|
|
if (is_win) {
|
|
if (!enable_iterator_debugging) {
|
|
# Iterator debugging is enabled by default by the compiler on debug
|
|
# builds, and we have to tell it to turn it off.
|
|
defines += [ "_HAS_ITERATOR_DEBUGGING=0" ]
|
|
}
|
|
} else if (is_linux && current_cpu == "x64" && enable_iterator_debugging) {
|
|
# Enable libstdc++ debugging facilities to help catch problems early, see
|
|
# http://crbug.com/65151 .
|
|
# TODO(phajdan.jr): Should we enable this for all of POSIX?
|
|
defines += [ "_GLIBCXX_DEBUG=1" ]
|
|
}
|
|
}
|
|
|
|
config("release") {
|
|
defines = [ "NDEBUG" ]
|
|
|
|
# Sanitizers.
|
|
if (is_tsan) {
|
|
defines += [
|
|
"DYNAMIC_ANNOTATIONS_ENABLED=1",
|
|
"WTF_USE_DYNAMIC_ANNOTATIONS=1",
|
|
]
|
|
} else {
|
|
defines += [ "NVALGRIND" ]
|
|
if (!is_nacl) {
|
|
# NaCl always enables dynamic annotations. Currently this value is set to
|
|
# 1 for all .nexes.
|
|
defines += [ "DYNAMIC_ANNOTATIONS_ENABLED=0" ]
|
|
}
|
|
}
|
|
}
|
|
|
|
# Default libraries ------------------------------------------------------------
|
|
|
|
# This config defines the default libraries applied to all targets.
|
|
config("default_libs") {
|
|
if (is_win) {
|
|
# TODO(brettw) this list of defaults should probably be smaller, and
|
|
# instead the targets that use the less common ones (e.g. wininet or
|
|
# winspool) should include those explicitly.
|
|
libs = [
|
|
"advapi32.lib",
|
|
"comdlg32.lib",
|
|
"dbghelp.lib",
|
|
"delayimp.lib",
|
|
"dnsapi.lib",
|
|
"gdi32.lib",
|
|
"kernel32.lib",
|
|
"msimg32.lib",
|
|
"odbc32.lib",
|
|
"odbccp32.lib",
|
|
"ole32.lib",
|
|
"oleaut32.lib",
|
|
"psapi.lib",
|
|
"shell32.lib",
|
|
"shlwapi.lib",
|
|
"user32.lib",
|
|
"usp10.lib",
|
|
"uuid.lib",
|
|
"version.lib",
|
|
"wininet.lib",
|
|
"winmm.lib",
|
|
"winspool.lib",
|
|
"ws2_32.lib",
|
|
|
|
# Please don't add more stuff here. We should actually be making this
|
|
# list smaller, since all common things should be covered. If you need
|
|
# some extra libraries, please just add a libs = [ "foo.lib" ] to your
|
|
# target that needs it.
|
|
]
|
|
} else if (is_android) {
|
|
libs = [
|
|
"dl",
|
|
"m",
|
|
]
|
|
} else if (is_mac) {
|
|
# Targets should choose to explicitly link frameworks they require. Since
|
|
# linking can have run-time side effects, nothing should be listed here.
|
|
libs = []
|
|
} else if (is_ios) {
|
|
# The libraries listed here will be specified for both the target and the
|
|
# host. Only the common ones should be listed here.
|
|
libs = [
|
|
"CoreFoundation.framework",
|
|
"CoreGraphics.framework",
|
|
"CoreText.framework",
|
|
"Foundation.framework",
|
|
]
|
|
} else if (is_linux) {
|
|
libs = [
|
|
"dl",
|
|
"rt",
|
|
]
|
|
}
|
|
}
|
|
|
|
# Executable configs -----------------------------------------------------------
|
|
|
|
# Windows linker setup for EXEs and DLLs.
|
|
if (is_win) {
|
|
_windows_linker_configs = [
|
|
"//build/config/win:sdk_link",
|
|
"//build/config/win:common_linker_setup",
|
|
]
|
|
}
|
|
|
|
# This config defines the configs applied to all executables.
|
|
config("executable_config") {
|
|
configs = []
|
|
|
|
if (is_win) {
|
|
configs += _windows_linker_configs
|
|
} else if (is_mac) {
|
|
configs += [
|
|
"//build/config/mac:mac_dynamic_flags",
|
|
"//build/config/mac:mac_executable_flags",
|
|
]
|
|
} else if (is_ios) {
|
|
configs += [ "//build/config/ios:ios_dynamic_flags" ]
|
|
} else if (is_linux || is_android) {
|
|
configs += [ "//build/config/gcc:executable_ldconfig" ]
|
|
if (is_android) {
|
|
configs += [ "//build/config/android:executable_config" ]
|
|
} else if (is_chromecast) {
|
|
configs += [ "//build/config/chromecast:executable_config" ]
|
|
}
|
|
}
|
|
|
|
# If we're using the prebuilt instrumented libraries with the sanitizers, we
|
|
# need to add ldflags to every binary to make sure they are picked up.
|
|
if (prebuilt_instrumented_libraries_available) {
|
|
configs += [ "//third_party/instrumented_libraries:prebuilt_ldflags" ]
|
|
}
|
|
if (use_locally_built_instrumented_libraries) {
|
|
configs += [ "//third_party/instrumented_libraries:locally_built_ldflags" ]
|
|
}
|
|
configs += [ "//build/config/sanitizers:link_executable" ]
|
|
}
|
|
|
|
# Shared library configs -------------------------------------------------------
|
|
|
|
# This config defines the configs applied to all shared libraries.
|
|
config("shared_library_config") {
|
|
configs = []
|
|
|
|
if (is_win) {
|
|
configs += _windows_linker_configs
|
|
} else if (is_mac) {
|
|
configs += [ "//build/config/mac:mac_dynamic_flags" ]
|
|
} else if (is_ios) {
|
|
configs += [ "//build/config/ios:ios_dynamic_flags" ]
|
|
} else if (is_chromecast) {
|
|
configs += [ "//build/config/chromecast:shared_library_config" ]
|
|
}
|
|
|
|
# If we're using the prebuilt instrumented libraries with the sanitizers, we
|
|
# need to add ldflags to every binary to make sure they are picked up.
|
|
if (prebuilt_instrumented_libraries_available) {
|
|
configs += [ "//third_party/instrumented_libraries:prebuilt_ldflags" ]
|
|
}
|
|
if (use_locally_built_instrumented_libraries) {
|
|
configs += [ "//third_party/instrumented_libraries:locally_built_ldflags" ]
|
|
}
|
|
configs += [ "//build/config/sanitizers:link_shared_library" ]
|
|
}
|
|
|
|
# Add this config to your target to enable precompiled headers.
|
|
#
|
|
# Precompiled headers are done on a per-target basis. If you have just a couple
|
|
# of files, the time it takes to precompile (~2 seconds) can actually be longer
|
|
# than the time saved. On a Z620, a 100 file target compiles about 2 seconds
|
|
# faster with precompiled headers, with greater savings for larger targets.
|
|
#
|
|
# Recommend precompiled headers for targets with more than 50 .cc files.
|
|
config("precompiled_headers") {
|
|
if (!is_official_build && !use_goma && !disable_precompiled_headers) {
|
|
if (is_win) {
|
|
# This is a string rather than a file GN knows about. It has to match
|
|
# exactly what's in the /FI flag below, and what might appear in the
|
|
# source code in quotes for an #include directive.
|
|
precompiled_header = "build/precompile.h"
|
|
|
|
# This is a file that GN will compile with the above header. It will be
|
|
# implicitly added to the sources (potentially multiple times, with one
|
|
# variant for each language used in the target).
|
|
precompiled_source = "//build/precompile.cc"
|
|
|
|
# Force include the header.
|
|
cflags = [ "/FI$precompiled_header" ]
|
|
|
|
# Disable warning for "this file was empty after preprocessing". This
|
|
# error is generated only in C mode for ANSI compatibility. It conflicts
|
|
# with precompiled headers since the source file that's "compiled" for
|
|
# making the precompiled header is empty.
|
|
#
|
|
# This error doesn't happen every time. In VS2013, it seems if the .pch
|
|
# file doesn't exist, no error will be generated (probably MS tested this
|
|
# case but forgot the other one?). To reproduce this error, do a build,
|
|
# then delete the precompile.c.obj file, then build again.
|
|
cflags_c = [ "/wd4206" ]
|
|
} else if (is_mac) {
|
|
precompiled_header = "build/precompile.h"
|
|
precompiled_source = "//build/precompile.h"
|
|
}
|
|
}
|
|
}
|