Bug 1079385 - Send NS_NETWORK_LINK_DATA_CHANGED event on Mac OS X. r=joshmoz

netwerk/system/mac/nsNetworkLinkService.h

@@ -9,6 +9,7 @@
 #include "nsIObserver.h"
 
 #include <SystemConfiguration/SCNetworkReachability.h>
+#include <SystemConfiguration/SystemConfiguration.h>
 
 class nsNetworkLinkService : public nsINetworkLinkService,
                              public nsIObserver
@@ -30,14 +31,22 @@ private:
     bool mLinkUp;
     bool mStatusKnown;
 
+    // Toggles allowing the sending of network-changed event.
+    bool mAllowChangedEvent;
+
     SCNetworkReachabilityRef mReachability;
     CFRunLoopRef mCFRunLoop;
+    CFRunLoopSourceRef mRunLoopSource;
+    SCDynamicStoreRef mStoreRef;
 
     void UpdateReachability();
-    void SendEvent();
+    void SendEvent(bool aNetworkChanged);
     static void ReachabilityChanged(SCNetworkReachabilityRef target,
                                     SCNetworkConnectionFlags flags,
                                     void *info);
+    static void IPConfigChanged(SCDynamicStoreRef store,
+                                CFArrayRef changedKeys,
+                                void *info);
 };
 
 #endif /* NSNETWORKLINKSERVICEMAC_H_ */

netwerk/system/mac/nsNetworkLinkService.mm

@@ -9,10 +9,47 @@
 #include "nsServiceManagerUtils.h"
 #include "nsString.h"
 #include "nsCRT.h"
+#include "mozilla/Preferences.h"
 
 #import <Cocoa/Cocoa.h>
 #import <netinet/in.h>
 
+#define NETWORK_NOTIFY_CHANGED_PREF "network.notify.changed"
+
+using namespace mozilla;
+
+// If non-successful, extract the error code and return it.  This
+// error code dance is inspired by
+// http://developer.apple.com/technotes/tn/tn1145.html
+static OSStatus getErrorCodeBool(Boolean success)
+{
+    OSStatus err = noErr;
+    if (!success) {
+        int scErr = ::SCError();
+        if (scErr == kSCStatusOK) {
+            scErr = kSCStatusFailed;
+        }
+        err = scErr;
+    }
+    return err;
+}
+
+// If given a NULL pointer, return the error code.
+static OSStatus getErrorCodePtr(const void *value)
+{
+    return getErrorCodeBool(value != NULL);
+}
+
+// Convenience function to allow NULL input.
+static void CFReleaseSafe(CFTypeRef cf)
+{
+    if (cf) {
+        // "If cf is NULL, this will cause a runtime error and your
+        // application will crash." / Apple docs
+        ::CFRelease(cf);
+    }
+}
+
 NS_IMPL_ISUPPORTS(nsNetworkLinkService,
                   nsINetworkLinkService,
                   nsIObserver)
@@ -20,8 +57,11 @@ NS_IMPL_ISUPPORTS(nsNetworkLinkService,
 nsNetworkLinkService::nsNetworkLinkService()
     : mLinkUp(true)
     , mStatusKnown(false)
-    , mReachability(NULL)
-    , mCFRunLoop(NULL)
+    , mAllowChangedEvent(true)
+    , mReachability(nullptr)
+    , mCFRunLoop(nullptr)
+    , mRunLoopSource(nullptr)
+    , mStoreRef(nullptr)
 {
 }
 
@@ -65,6 +105,17 @@ nsNetworkLinkService::Observe(nsISupports *subject,
     return NS_OK;
 }
 
+/* static */
+void
+nsNetworkLinkService::IPConfigChanged(SCDynamicStoreRef aStoreREf,
+                                      CFArrayRef aChangedKeys,
+                                      void *aInfo)
+{
+    nsNetworkLinkService *service =
+        static_cast<nsNetworkLinkService*>(aInfo);
+    service->SendEvent(true);
+}
+
 nsresult
 nsNetworkLinkService::Init(void)
 {
@@ -77,6 +128,9 @@ nsNetworkLinkService::Init(void)
     rv = observerService->AddObserver(this, "xpcom-shutdown", false);
     NS_ENSURE_SUCCESS(rv, rv);
 
+    Preferences::AddBoolVarCache(&mAllowChangedEvent,
+                                 NETWORK_NOTIFY_CHANGED_PREF, true);
+
     // If the network reachability API can reach 0.0.0.0 without
     // requiring a connection, there is a network interface available.
     struct sockaddr_in addr;
@@ -100,6 +154,67 @@ nsNetworkLinkService::Init(void)
         return NS_ERROR_NOT_AVAILABLE;
     }
 
+    SCDynamicStoreContext storeContext = {0, this, NULL, NULL, NULL};
+    mStoreRef =
+        ::SCDynamicStoreCreate(NULL,
+                               CFSTR("AddIPAddressListChangeCallbackSCF"),
+                               IPConfigChanged, &storeContext);
+
+    CFStringRef patterns[2] = {NULL, NULL};
+    OSStatus err = getErrorCodePtr(mStoreRef);
+    if (err == noErr) {
+        // This pattern is "State:/Network/Service/[^/]+/IPv4".
+        patterns[0] =
+            ::SCDynamicStoreKeyCreateNetworkServiceEntity(NULL,
+                                                          kSCDynamicStoreDomainState,
+                                                          kSCCompAnyRegex,
+                                                          kSCEntNetIPv4);
+        err = getErrorCodePtr(patterns[0]);
+        if (err == noErr) {
+            // This pattern is "State:/Network/Service/[^/]+/IPv6".
+            patterns[1] =
+                ::SCDynamicStoreKeyCreateNetworkServiceEntity(NULL,
+                                                              kSCDynamicStoreDomainState,
+                                                              kSCCompAnyRegex,
+                                                              kSCEntNetIPv6);
+            err = getErrorCodePtr(patterns[1]);
+        }
+    }
+
+    CFArrayRef patternList = NULL;
+    // Create a pattern list containing just one pattern,
+    // then tell SCF that we want to watch changes in keys
+    // that match that pattern list, then create our run loop
+    // source.
+    if (err == noErr) {
+        patternList = ::CFArrayCreate(NULL, (const void **) patterns,
+                                      2, &kCFTypeArrayCallBacks);
+        if (!patternList) {
+            err = -1;
+        }
+    }
+    if (err == noErr) {
+        err =
+            getErrorCodeBool(::SCDynamicStoreSetNotificationKeys(mStoreRef,
+                                                                 NULL,
+                                                                 patternList));
+    }
+
+    if (err == noErr) {
+        mRunLoopSource =
+            ::SCDynamicStoreCreateRunLoopSource(NULL, mStoreRef, 0);
+        err = getErrorCodePtr(mRunLoopSource);
+    }
+
+    CFReleaseSafe(patterns[0]);
+    CFReleaseSafe(patterns[1]);
+    CFReleaseSafe(patternList);
+
+    if (err != noErr) {
+        CFReleaseSafe(mStoreRef);
+        return NS_ERROR_NOT_AVAILABLE;
+    }
+
     // Get the current run loop.  This service is initialized at startup,
     // so we shouldn't run in to any problems with modal dialog run loops.
     mCFRunLoop = [[NSRunLoop currentRunLoop] getCFRunLoop];
@@ -111,6 +226,8 @@ nsNetworkLinkService::Init(void)
     }
     ::CFRetain(mCFRunLoop);
 
+    ::CFRunLoopAddSource(mCFRunLoop, mRunLoopSource, kCFRunLoopDefaultMode);
+
     if (!::SCNetworkReachabilityScheduleWithRunLoop(mReachability, mCFRunLoop,
                                                     kCFRunLoopDefaultMode)) {
         NS_WARNING("SCNetworkReachabilityScheduleWIthRunLoop failed.");
@@ -135,11 +252,19 @@ nsNetworkLinkService::Shutdown()
         NS_WARNING("SCNetworkReachabilityUnscheduleFromRunLoop failed.");
     }
 
+    CFRunLoopRemoveSource(mCFRunLoop, mRunLoopSource, kCFRunLoopDefaultMode);
+
     ::CFRelease(mReachability);
-    mReachability = NULL;
+    mReachability = nullptr;
 
     ::CFRelease(mCFRunLoop);
-    mCFRunLoop = NULL;
+    mCFRunLoop = nullptr;
+
+    ::CFRelease(mStoreRef);
+    mStoreRef = nullptr;
+
+    ::CFRelease(mRunLoopSource);
+    mRunLoopSource = nullptr;
 
     return NS_OK;
 }
@@ -165,7 +290,7 @@ nsNetworkLinkService::UpdateReachability()
 }
 
 void
-nsNetworkLinkService::SendEvent()
+nsNetworkLinkService::SendEvent(bool aNetworkChanged)
 {
     nsCOMPtr<nsIObserverService> observerService =
         do_GetService("@mozilla.org/observer-service;1");
@@ -173,11 +298,17 @@ nsNetworkLinkService::SendEvent()
         return;
 
     const char *event;
-    if (!mStatusKnown)
+    if (aNetworkChanged) {
+        if (!mAllowChangedEvent) {
+            return;
+        }
+        event = NS_NETWORK_LINK_DATA_CHANGED;
+    } else if (!mStatusKnown) {
         event = NS_NETWORK_LINK_DATA_UNKNOWN;
-    else
+    } else {
         event = mLinkUp ? NS_NETWORK_LINK_DATA_UP
-                        : NS_NETWORK_LINK_DATA_DOWN;
+            : NS_NETWORK_LINK_DATA_DOWN;
+    }
 
     observerService->NotifyObservers(static_cast<nsINetworkLinkService*>(this),
                                      NS_NETWORK_LINK_TOPIC,
@@ -194,5 +325,5 @@ nsNetworkLinkService::ReachabilityChanged(SCNetworkReachabilityRef target,
         static_cast<nsNetworkLinkService*>(info);
 
     service->UpdateReachability();
-    service->SendEvent();
+    service->SendEvent(false);
 }