/* This Source Code Form is subject to the terms of the Mozilla Public
 * License, v. 2.0. If a copy of the MPL was not distributed with this
 * file, You can obtain one at http://mozilla.org/MPL/2.0/. */

include protocol PBackgroundIDBFactory;
include protocol PBackgroundTest;
include protocol PBlob;
include protocol PBroadcastChannel;
include protocol PCache;
include protocol PCacheStorage;
include protocol PCacheStreamControl;
include protocol PFileDescriptorSet;
include protocol PVsync;
include protocol PMedia;

include DOMTypes;
include PBackgroundSharedTypes;
include PBackgroundIDBSharedTypes;
include ServiceWorkerRegistrarTypes;

using mozilla::dom::cache::Namespace from "mozilla/dom/cache/Types.h";
include "mozilla/dom/cache/IPCUtils.h";

namespace mozilla {
namespace ipc {

sync protocol PBackground
{
  manages PBackgroundIDBFactory;
  manages PBackgroundTest;
  manages PBlob;
  manages PBroadcastChannel;
  manages PCache;
  manages PCacheStorage;
  manages PCacheStreamControl;
  manages PFileDescriptorSet;
  manages PVsync;
  manages PMedia;

parent:
  // Only called at startup during mochitests to check the basic infrastructure.
  PBackgroundTest(nsCString testArg);

  PBackgroundIDBFactory(LoggingInfo loggingInfo);

  PVsync();
  PMedia();

  PBroadcastChannel(PrincipalInfo pInfo, nsString origin, nsString channel,
                    bool privateBrowsing);

  RegisterServiceWorker(ServiceWorkerRegistrationData data);
  UnregisterServiceWorker(PrincipalInfo principalInfo,
                          nsString scope);
  ShutdownServiceWorkerRegistrar();

  PCacheStorage(Namespace aNamespace, PrincipalInfo aPrincipalInfo);

child:
  PCache();
  PCacheStreamControl();

both:
  PBlob(BlobConstructorParams params);

  PFileDescriptorSet(FileDescriptor fd);
};

} // namespace ipc
} // namespace mozilla